Interactive Media Design Review 1999/Interactive Media Design Review 1999.iso/pc/Demos/Bombardier_PC/BSCRIPTS.CST/00110_Script_returnToQTVRfield

Text File | 1999-04-25 | 4KB | 138 lines

-- ⌐ 1998 @radical.media, inc. & Concurrent New Media Group, L.L.C.
-- Developed for Bombardier, Inc.
--
-- All programming developed by:
-- Robert Fabricant, Valerie Valoueva, Ossi Shaked,
-- Henry Sauvageot, Chris Howell & Chris Girand
--
-- Use of this code by parties other than @radical.media, inc. or their
--agents
-- without the express written consent of @radical.media, inc. AND Concurrent
-- New Media Group, L.L.C. is strictly prohibited.
------------------------------------------------------

--Each "return to aircraft" button consists of two elements: #bmp "Picture" and #richText "Field". Both elements are linked and should be percieved by user as a whole: one element's rollover triggers the other element's rollover. This script is a "Field"'s behavior .

property mySprite, neutralName, HiliteButtonName, NeutralButtonName,buttonSprite, myRect
global comeFromQTVR, gRtrnPln, retFrame


on new me
  global returnSoundPlayed --sound trigger
  -- Button is only visible if this detail was
  -- navigated from a QTVR interior or exterior sections
  if comeFromQTVR then
    set mySprite = the spriteNum of me
    set fieldIsHilited = FALSE
    set neutralName = "r_field"

    --figure out "Picture"'s sprite number and  cast
    --members name since "field"'s rollovers also have to change "Picture"'s graphics
    set neutralButtonName = getNeuButtonName (me)
    set HiliteButtonName = neutralButtonName & "-hil"
    set buttonSprite = mySprite+1
    set the member of sprite mySprite = member neutralName

    --Rollover sound effect shouldn't play again
    --if mouse leaves "field" and rolles over "Picture"
    --and vice versa. Boundaries between "field" and "Picture"
    --sould be seamless. The following code calculates an
    --imaginary rectangle around the button to set the sound
    --trigger off if mouse is within that rectangle.
    set textWidth = the width of member neutralName
    set textHeight = the height of member neutralName
    set butWidth = the width of member neutralButtonName
    set butHeight = the height of member neutralButtonName
    if the left of sprite mySprite > the left of sprite buttonSprite then
      set startH = the left of sprite buttonSprite - butWidth/2
      set startV = the top of sprite buttonSprite - butHeight/2

    else
      set startH = the left of sprite mySprite
      set startV = the top of sprite mySprite

    end if
    set startPoint = point(startH,startV)
    set endH = startH + butWidth + textWidth
    set endV = startV + max(butHeight,textHeight)
    set endPoint = point(endH,endV)
    set myRect = rect(startPoint,endPoint)


    set returnSoundPlayed = FALSE
    --    put myRect
  end if


end



on exitFrame me
  global returnSoundPlayed
  if comeFromQTVR then
    set mouseLoc = point(the mouseH, the mouseV)
    if inside (mouseLoc,myRect) then
      if not returnSoundPlayed then
        puppetsound 3, "subRollOld"
        set returnSoundPlayed = TRUE
      end if
    else
      set returnSoundPlayed = FALSE
    end if
  end if


end




on mouseEnter me
  if comeFromQTVR then

    set the member of sprite buttonSprite = member  HiliteButtonName
  end if

end

on mouseLeave me
  if comeFromQTVR then

    set the member of sprite buttonSprite= member  NeutralButtonName


  end if

end

on mouseUp me
  if comeFromQTVR then
    if gRtrnPln = "EXT" then --if came from the QTVR exterior
      go to retFrame
    else
      go to frame "qtvr" --if came from the QTVR interior
    end if

    puppetsound 3, "mouse5"
  end if
  cursor -1
end


on getNeuButtonName me
   set Name = neutralName
  repeat with i = the Number of Chars of Name down to 1
    if char i of Name <> "_" then
      delete char i of Name
    else
      delete char i of Name
      exit repeat
    end if
  end repeat
  return Name
end